$$ WPLOT plots the actual screen with variable scale and papersize
$$ centered on the paper to the SSP(Self-Service-Plotter)-Station.
$$ Created by Thomas Kaufmann & Siegfried Retter 11.Jan.89. hpWAD
DEF WPLOT {"ENTer the paper size (DEFAULT=D)." PS "D";
           "ENTer the scale factor (DEFAULT=1)." SF "1";
           "ENTer Plotname (DEFAULT=1)." PN "1"}
   "DEF PXD (P2X-P1X);
    DEF PYD (P2Y-P1Y);
    DEF TKflag 0; "
   "(IFELSE('{PS}'='C','DEF PSXmil 20192; DEF PSYmil 16072; ',
     IFELSE('{PS}'='D','DEF PSXmil 32384; DEF PSYmil 21152; ',
     IFELSE('{PS}'='E','DEF PSXmil 42544; DEF PSYmil 33344; ','TKerr1 DEF TKflag 1; ') ) )) " 
   "(IFELSE(SYSTEM_UNIT_TYPE='MIL',' ',
     IFELSE(SYSTEM_UNIT_TYPE='MM','DEF PSXmil (PSXmil/39.370); DEF PSYmil (PSYmil/39.370); ',
     IFELSE(SYSTEM_UNIT_TYPE='CM','DEF PSXmil (PSXmil/393.70); DEF PSYmil (PSYmil/393.70); ','TKerr2 DEF TKflag 2; ') ) )) "
   "(IFELSE(((PYD*{SF})>PSYmil) AND (TKflag<>1),'TKerr3 DEF TKflag 3; ',' ')) "
   "(IFELSE(TKflag=0,'TKplot {PS} {SF} {PN} ',' ')) ";
    
    DEF TKplot {PS;SF;PN "plotting."} 
       "DEF PX1neu (P1X-(PSXmil/{SF}-PXD)/2);
        DEF PY1neu (P1Y-(PSYmil/{SF}-PYD)/2);
        DEF PX2neu (PX1neu+PXD);
        DEF PY2neu (PY1neu+PYD);
        WIN (PX1neu),(PY1neu) (PX2neu),(PY2neu); "
       "(IFELSE('{PS}'<>'C','PLO :S{SF} :V20 :P{PS} :T7585B #46:PC_{PS}_{PN}.ASC; ',
                            'PLO :S{SF} :V20 :P{PS} :A :T7585B #46:PC_{PS}_{PN}.ASC; ')) "
       "LAST 
        TKmessage ";
            
    DEF TKerr1 {"Unknown papersize. Only C,D,E are valid."} " ";
    DEF TKerr2 {"Unknown dimension units. Only MIL,MM,CM are valid."} " ";
    DEF TKerr3 {"The max. scale factor is"} 
       "EVA (PSYmil/PYD);";
    DEF TKmessage {"The WINDOW-plot has finished."} " ";
$$ End of WPLOT----------------------------------------------------------------


$$ MM & MC created by Thomas Kaufmann & Siegfried Retter in Jan.88-------------
DEF MM {"Select reference point." X1;Y1}
   "POINT {X1},{Y1}; 
    DEF PX1 {X1} ;
    DEF PY1 {Y1} ;
    MM1 ";
    
    DEF MM1 {"Select destination point." X2;Y2}
       "POINT {X2},{Y2};
        DEF PX2 {X2} ;
        DEF PY2 {Y2} ;
        DEF PXD (PX2-PX1);   
        DEF PYD (PY2-PY1); 
        MULTI_MOVE ";
    
    DEF MULTI_MOVE {"Select component or press STOP ; " PX3;PY3}
       "MOVE {PX3},{PY3} {PX3},{PY3} ({PX3}+PXD),({PY3}+PYD); "
       "MULTI_MOVE ";
$$ End of MM.
    
DEF MC {"Select reference point." X1;Y1}
   "POINT {X1},{Y1}; 
    DEF PX1 {X1} ;
    DEF PY1 {Y1} ;
    MC1 ";
    
    DEF MC1 {"Select destination point." X2;Y2}
       "POINT {X2},{Y2};
        DEF PX2 {X2} ;
        DEF PY2 {Y2} ;
        DEF PXD (PX2-PX1);   
        DEF PYD (PY2-PY1); 
        MULTI_COPY ";
    
    DEF MULTI_COPY {"Select component or press STOP ; " PX3;PY3}
       "COPY {PX3},{PY3} {PX3},{PY3} ({PX3}+PXD),({PY3}+PYD); "
       "MULTI_COPY ";
$$ End of MC.


$$ TKfind finds a searchstring and positions the identified part in
$$        the center of the screen.
DEF TKfind {"Enter the search string." TKss}
   "IDE '{TKss}'; "
   "WIN ((SYSTEM_LL_X+SYSTEM_UR_X)/2),((SYSTEM_LL_Y+SYSTEM_UR_Y)/2); ";